Adiabatic Transfer from Low to high field

We will find the Hamiltonian as a function of magnetic field for a two spin system with a chemical shift difference and a J-coupling between the spins. Under adiabatic transport conditions a populated state will remain an eigenstate of the Hamiltonian at all times, therefore the task at hand consists in finding the eigenstates as a function of magnetic field from zero to infinity.

Setting up the 2-spin matrices for spins I and S

Pauli matrices:

σx=1/2*(({{0, 1}, {1, 0}}));
σy=1/2*(({{0, -I}, {I, 0}}));
σz=1/2*(({{1, 0}, {0, -1}}));

id=IdentityMatrix[2];

Two spin matrices:

Ix=KroneckerProduct[σx,id];
Sx=KroneckerProduct[id,σx];
Iy=KroneckerProduct[σy,id];
Sy=KroneckerProduct[id,σy];
Iz=KroneckerProduct[σz,id];
Sz=KroneckerProduct[id,σz];

Defining a general 2-spin Hamiltonian with distinct frequencies for I and S and a J-coupling between I and S. In this Hamiltonian (Subscript[ν, 1]) and (Subscript[ν, 2]) change as a function of magnetic field. J is independent of the magnetic field.

H=(Subscript[ν, 1])*Iz+(Subscript[ν, 2])*Sz+J(Ix.Sx+Iy.Sy+Iz.Sz)=H=Δν(Iz-Sz)/2+Σν(Iz+Sz)/2+J(Ix.Sx+Iy.Sy+Iz.Sz)
Note Δν=(Subscript[ν, 1])-(Subscript[ν, 2])    and   Σν=(Subscript[ν, 1])+(Subscript[ν, 2])

(H=Δν(Iz-Sz)/2+Σν(Iz+Sz)/2+J(Ix.Sx+Iy.Sy+Iz.Sz))//MatrixForm

Finding the Eigenvalues and Eigenvectors at any given magnetic field:

Simplify[Eigenvalues[H]]

Eigenvectors[H]

In the limit of 0 magnetic field, i.e. no frequency difference, these states correspond to S0, T0, T- and T+.
T+ and T- also correspond to αα and ββ and are independent of the magnetic field. We will focus on the singelt state S0 and analyze how this eigenstate changes as a function of magnetic field

S0={0,-((-Δν+(Sqrt[(J^2)+((Δν)^2)]))/J),1,0};
T0={0,-((-Δν-(Sqrt[(J^2)+((Δν)^2)]))/J),1,0};

The states above are not normalized and will be normalized in the following:

Clear[J,Δν]
S0n=Simplify[Normalize[S0],Assumptions->{Δν>0,J>0}]
T0n=Simplify[Normalize[T0],Assumptions->{Δν>0,J>0}]

With theses normalized, magnetic field dependent states at hand, we can calculate the density matrix as function of magnetic field for adiabatic transport (i.e. the population remains in an eigenstate of the Hamiltonian at all magnetic fields)

For S0 as a function of magnetic field we find:

(rhoS0=FullSimplify[Outer[Times,S0n,Transpose[S0n]]])//MatrixForm

For T0 as a function of magnetic field we find :

(rhoT0=FullSimplify[Outer[Times,T0n,Transpose[T0n]]])//MatrixForm

These expressions can now be compared to the expressions in the main manuscript to find that they are identical.

For S0, we express this magnetic field dependent density matrix as 
1/4I-(Subscript[I, z])(Subscript[S, z])-(J/(Sqrt[(J^2)+((Δν)^2)])) ((Subscript[I, x])(Subscript[S, x])+(Subscript[I, y])(Subscript[S, y]))-((Δν)/( 2(Sqrt[(J^2)+((Δν)^2)])))((Subscript[I, z])-(Subscript[S, z]))

(1/4*IdentityMatrix[4]-Iz.Sz-J/(Sqrt[Δν^2+J^2])*(Ix.Sx+Iy.Sy)-Δν/(Sqrt[Δν^2+J^2])*1/2*(Iz-Sz))//MatrixForm

By comparison to the expression for S0 above, they are identical.

For T0, we express the magnetic field dependent density matrix as 
1/4I-(Subscript[I, z])(Subscript[S, z])+(J/(Sqrt[(J^2)+((Δν)^2)])) ((Subscript[I, x])(Subscript[S, x])+(Subscript[I, y])(Subscript[S, y]))+((Δν)/( 2(Sqrt[(J^2)+((Δν)^2)])))((Subscript[I, z])-(Subscript[S, z]))

(1/4*IdentityMatrix[4]-Iz.Sz+J/(Sqrt[Δν^2+J^2])*(Ix.Sx+Iy.Sy)+Δν/(Sqrt[Δν^2+J^2])*1/2*(Iz-Sz))//MatrixForm

If we introduce the angle θ as tan(θ)=Δν/J and arctan(Δν/J)=θ through:

then we can express, 
(J/(Sqrt[(J^2)+((Δν)^2)]))= cos(θ) and ((Δν)/( (Sqrt[(J^2)+((Δν)^2)])))= sin(θ), under the condition that Δν  and J are both positive, which also implies that θ must be between 0 and π/2.
We can use this information to further simplify our equations and write them as:
for the singlet as a function of magnetic field:
1/4I-(Subscript[I, z])(Subscript[S, z])-cos(θ) ((Subscript[I, x])(Subscript[S, x])+(Subscript[I, y])(Subscript[S, y]))-1/2 sin(θ)((Subscript[I, z])-(Subscript[S, z])),
and for the triplet-zero as a function of magnetic field:
1/4I-(Subscript[I, z])(Subscript[S, z])+cos(θ) ((Subscript[I, x])(Subscript[S, x])+(Subscript[I, y])(Subscript[S, y]))+1/2 sin(θ)((Subscript[I, z])-(Subscript[S, z])),

Analyzing the same problem by introducing θ from the get-go in the Hamiltonian:

(Hangle=Sin[θ]*(Iz-Sz)/2+Cos[θ]*(Ix.Sx+Iy.Sy+Iz.Sz))//MatrixForm

Finding the Eigenvectors:

(eigs=FullSimplify[Eigenvectors[Hangle],Assumptions->Pi/2>θ>0])

Normalizing the eigenvectors for S0 and T0:

S0na=FullSimplify[Normalize[{0,-Sec[θ]+Tan[θ],1,0}],Assumptions->{0<θ<Pi/2}]

T0na=FullSimplify[Normalize[{0,Sec[θ]+Tan[θ],1,0}],Assumptions->{0<θ<Pi/2}]

Using these vectors (T0, S0) to obtain the magnetic field dependent density matrices:

(singletdensitymatrix=FullSimplify[Outer[Times,S0na,Transpose[S0na]],Assumptions->{0<θ<Pi/2}])//MatrixForm

(({{0, 0, 0, 0}, {0, (1/2)-((Δν)/(2 (Sqrt[(J^2)+((Δν)^2)]))), -(J/(2 (Sqrt[(J^2)+((Δν)^2)]))), 0}, {0, -(J/(2 (Sqrt[(J^2)+((Δν)^2)]))), (1/2) (1+((Δν)/(Sqrt[(J^2)+((Δν)^2)]))), 0}, {0, 0, 0, 0}}))

Showing that (1/(1+(((Sec[θ]-Tan[θ]))^2))) is equal to (1/2+Sin[θ]/2)

FullSimplify[(1/(1+(((Sec[θ]-Tan[θ]))^2)))-(1/2+Sin[θ]/2),Assumptions->{J>0,Δν>0}]

(T0densitymatrix=Simplify[Outer[Times,T0na,Transpose[T0na]]])//MatrixForm

Showing that (1/(1+(((Sec[θ]+Tan[θ]))^2))) is equal to (1/2-Sin[θ]/2)

FullSimplify[(1/(1+(((Sec[θ]+Tan[θ]))^2)))-(1/2-Sin[θ]/2),Assumptions->{J>0,Δν>0}]

Showing that  ((Δν)/( (Sqrt[(J^2)+((Δν)^2)])))is equal to Sin[ArcTan[Δν/J]]=sin(θ)

FullSimplify[((Δν)/( (Sqrt[(J^2)+((Δν)^2)])))-Sin[ArcTan[Δν/J]],Assumptions->{J>0,Δν>0}]

Showing that  (J/( (Sqrt[(J^2)+((Δν)^2)])))is equal to Cos[ArcTan[Δν/J]]=cos(θ)

FullSimplify[(J/(Sqrt[(J^2)+((Δν)^2)]))-Cos[ArcTan[Δν/J]],Assumptions->{J>0,Δν>0}]