J2 FINITE CONSTITUTIVE EQUATION

(*initial definition of prestretch*)
Id={{1,0,0},{0,1,0},{0,0,1}};
F={{λr,0,0},{0,λθ,0},{0,0,λz}};
J=Det[F]
B=F.Transpose[F];

(*incompressibility (J=1) AND axisymmetry conditions (λr=λθ)*)
λθinc=Solve[J==1,λθ][[1]]
axisymm=Solve[(J/.λθ->λr)==1,λr][[2]]
(*check*)
J/.λθ->λr/.axisymm

(*Cauchy stress for the incompressible material eq(2.1)*)
T=-ππ*Id+αp1*B+αm1*Inverse[B];
solα=FullSimplify[Expand[Solve[{σz-σr==T[[3,3]]-T[[1,1]],σθ-σr==T[[2,2]]-T[[1,1]]},{αp1,αm1}]]][[1]]

(*simplification of αp1 and αm1*)
αp1simp=(1/(((λz)^2)-((λr)^2)))(((λz)^2)(( σz-σθ)/(((λz)^2)-((λθ)^2)))-((λr)^2)(( σr-σθ)/(((λr)^2)-((λθ)^2))));
αm1simp=(1/(((λz)^2)-((λr)^2) ))((( σz-σθ)/(((λz)^2)-((λθ)^2)))-(( σr-σθ)/(((λr)^2)-((λθ)^2))));
(*check*)
FullSimplify[αp1simp-(αp1/.solα)]
FullSimplify[αm1simp-(αm1/.solα/.(J^2)->1)]

(*new notation for αp1, αm1*)
par1=(( σz-σθ)/(((λz)^2)-((λθ)^2)));
par2=(( σr-σθ)/(((λr)^2)-((λθ)^2)));
ααp1=(1/(((λz)^2)-((λr)^2)))(((λz)^2)par1-((λr)^2)par2);
FullSimplify[ααp1-αp1simp]
ααm1=(1/(((λz)^2)-((λr)^2) ))(par1-par2);
FullSimplify[ααm1-αm1simp]

(*J2 CONSTITUTIVE EQUATION with 0<N≤1*)
ϵeval={ϵe->(Sqrt[(2/3)(((Log[λr])^2)+((Log[λθ])^2)+((Log[λz])^2))])};
(*strain energy fct as a function of only λr and λz*)
W[λr_,λz_]:=Simplify[(K/(N+1))((ϵe)^(N+1))/.ϵeval/.λθinc]
(*through the chain rule*)
Δσzθ=FullSimplify[λz*D[W[λr,λz],λz]];
Δσrθ=FullSimplify[λr*D[W[λr,λz],λr]];
Print["σz-σθ=",Δσzθ]
Print["σr-σθ=",Δσrθ]

(*analysis of the limits of ϵe, par1, par2 for λr->((λz)^(-1/2))*)
ϵelim=FullSimplify[ϵe/.ϵeval/.λθinc/.axisymm,λz>0]
par1lim=FullSimplify[((Δσzθ)/(((λz)^2)-((λθ)^2)))/.λθinc/.axisymm,λz>0]
par2lim=FullSimplify[Limit[FullSimplify[((Δσrθ)/(((λr)^2)-((λθ)^2)))/.λθinc,λr>0],axisymm[[1]]],λz>0]

(*final expressions of αp1, αm1*)
ααp1fin=FullSimplify[ααp1/.par1->par1lim/.par2->par2lim/.axisymm/.Abs[Log[λz]]->ϵe]
ααm1fin=FullSimplify[ααm1/.par1->par1lim/.par2->par2lim/.axisymm/.Abs[Log[λz]]->ϵe]

(*check eqs(2.6)*)
FullSimplify[((K ((ϵe)^(N-1)) λz (1+((λz)^3)(3*Log[λz]-1)))/(3 (((((λz)^3)-1))^2)))-ααp1fin]
FullSimplify[((K ((ϵe)^(N-1)) ((λz)^2) (1-((λz)^3)+3*Log[λz]))/(3 (((((λz)^3)-1))^2)))-ααm1fin]